///////////////////////////////////////////////////////////////////////////////
//  F1 Add/Edit Entity                                                       //
///////////////////////////////////////////////////////////////////////////////
menu_entity = [toggleui "addentity"]
// menu_entity = [if (enthavesel) [toggleui "editentity"] [toggleui "addentity"]]

UImenu "editentity" [
   uifill 0.5 0.5 [
      UIbutton "" [uitext "ToDo" 0.8] 0.3 0.2 [hidetopui]
   ]
] [] [] [] "Edit Entity"

UImenu "addentity" [
   uispace 0.008 0.015 [
      uivlist 0 [
         uifill 0.5 0.032 [
            uitext (concatword "^f8/newent " $UI_enttype) 0.7
            uialign* -1 0
            uioutline $c_line ; uiclamp- 1 1 1 1
         ]
         uifill 0 0.025
         uihlist 0.005 [
            uivlist 0.005 [
               UIbutton "" [uitext "Envmap" 0.6]    0.2 0.04 [hideui "addentity" ; newent envmap]          -1 [uihover [UI_enttype = "envmap"]]
               UIbutton "" [uitext "Light" 0.6]     0.2 0.04 [hideui "addentity" ; showui "ent_light"]     -1 [uihover [UI_enttype = "light ^f4*"]]
               UIbutton "" [uitext "Spotlight" 0.6] 0.2 0.04 [hideui "addentity" ; showui "ent_spotlight"] -1 [uihover [UI_enttype = "spotlight ^f4*"]]
            ]
            uivlist 0.005 [
               UIbutton "" [uitext "Jumppad" 0.6]   0.2 0.04 [hideui "addentity" ; showui "ent_jumppad"]   -1 [uihover [UI_enttype = "jumppad ^f4*"]]
               UIbutton "" [uitext "Mapmodel" 0.6; UI_keyref 2 0.027 0.027 "F3"]  0.2 0.04 [hideui "addentity"; showui "mapmodel"]     -1 [uihover [UI_enttype = "mapmodel ^f4*"]]
               UIbutton "" [uitext "Particles" 0.6] 0.2 0.04 [hideui "addentity" ; showui "ent_particles"] -1 [uihover [UI_enttype = "particles ^f4*"]]
               UIbutton "" [uitext "Teleport" 0.6]  0.2 0.04 [hideui "addentity" ; showui "ent_teleport"]  -1 [uihover [UI_enttype = "teleport ^f4*"]]
               UIbutton "" [uitext "Teledest" 0.6]  0.2 0.04 [hideui "addentity" ; showui "ent_teledest"]  -1 [uihover [UI_enttype = "teledest ^f4*"]]
            ]
            uivlist 0.005 [
               UIbutton "" [uitext "Playerstart" 0.6]         0.2 0.04 [hideui "addentity" ; newent playerstart]   -1 [uihover [UI_enttype = "playerstart"]]
               UIbutton "" [uitext "Playerstart ^f1Azul" 0.6] 0.2 0.04 [hideui "addentity" ; newent playerstart 1] -1 [uihover [UI_enttype = "playerstart 1"]]
               UIbutton "" [uitext "Playerstart ^f3Rojo" 0.6] 0.2 0.04 [hideui "addentity" ; newent playerstart 2] -1 [uihover [UI_enttype = "playerstart 2"]]
               UIbutton "" [uitext "Flag ^f1Azul" 0.6]        0.2 0.04 [hideui "addentity" ; newent flag 1]        -1 [uihover [UI_enttype = "flag 1"]]
               UIbutton "" [uitext "Flag ^f3Rojo" 0.6]        0.2 0.04 [hideui "addentity" ; newent flag 2]        -1 [uihover [UI_enttype = "flag 2"]]
            ]
            uialign* -1 -1
         ]
         uifill 0 0.01
         UIbutton "hold2" [
            UIcheckbox $entselsnap 0.016
            uitext "Entity Snapping" 0.6
            UI_keyref 2 0.027 0.027 "7"
         ] 0.25 0.04 [entselsnap (! $entselsnap)]
      ]
   ]
] [
   UI_enttype = " "
   looplist a ["editentity" "ent_light" "ent_spotlight" "ent_jumppad" "mapmodel" "ent_particles" "ent_teleport" "ent_teledest"] [hideui $a]
] [] [] "Add Entity"

UI_lts = 128
UI_ltr = 127
UI_ltg = 127
UI_ltb = 127
UI_ltt = 0
UImenu "ent_light" [
   uispace 0.008 0.015 [
      uivlist 0 [
         uifill 0.5 0.032 [
            uitext (concatword "^f8/newent light " $UI_lts " " $UI_ltr " " $UI_ltg " " $UI_ltb " " $UI_ltt) 0.7
            uialign* -1 0
            uioutline $c_line ; uiclamp- 1 1 1 1
         ]
         uifill 0 0.025
         uitable 0.005 0.005 [
            uitablerow [
               uitext "Radius" 0.6
               UIhslider UI_lts 1 256 1 0.5 0.032 [uitext $UI_lts 0.6]
               uialign* -1 0
            ]
            uitablerow [
               uitext "Red" 0.6
               UIhslider UI_ltr 0 255 1 0.5 0.032 [uitext $UI_ltr 0.6]
               uialign* -1 0
            ]
            uitablerow [
               uitext "Green" 0.6
               UIhslider UI_ltg 0 255 1 0.5 0.032 [uitext $UI_ltg 0.6]
               uialign* -1 0
            ]
            uitablerow [
               uitext "Blue" 0.6
               UIhslider UI_ltb 0 255 1 0.5 0.032 [uitext $UI_ltb 0.6]
               uialign* -1 0
            ]
            uitablerow [
               uitext "Type" 0.6
               UIhslider UI_ltt 0 2 1 0.5 0.032 [uitext $UI_ltt 0.6]
               uialign* -1 0
            ]
         ]
         uifill 0 0.025
         UIbutton "" [uitext "Add" 0.6] 0.12 0.06 [hideui "ent_light" ; newent light $UI_lts $UI_ltr $UI_ltg $UI_ltb $UI_ltt]
      ]
   ]
] [] [] [] "Add Entity - Light"

UI_sla = 45
UImenu "ent_spotlight" [
   uispace 0.008 0.015 [
      uivlist 0 [
         uifill 0.5 0.032 [
            uitext (concatword "^f8/newent spotlight " $UI_sla) 0.7
            uialign* -1 0
            uioutline $c_line ; uiclamp- 1 1 1 1
         ]
         uifill 0 0.025
         uihlist 0.005 [
            uitext "Angle" 0.6
            UIhslider UI_sla 1 90 1 0.5 0.032 [uitext $UI_sla 0.6]
            uialign* -1 0
         ]
         uifill 0 0.025
         UIbutton "" [uitext "Add" 0.6] 0.12 0.06 [hideui "ent_spotlight" ; newent spotlight $UI_sla]
      ]
   ]
] [] [] [] "Add Entity - Spotlight"

UI_jph = 20
UI_jpx = 0
UI_jpy = 0
UImenu "ent_jumppad" [
   uispace 0.008 0.015 [
      uivlist 0 [
         uifill 0.5 0.032 [
            uitext (concatword "^f8/newent jumppad " $UI_jph " " $UI_jpx " " $UI_jpy " ") 0.7
            uialign* -1 0
            uioutline $c_line ; uiclamp- 1 1 1 1
         ]
         uifill 0 0.025
         uitable 0.005 0.005 [
            uitablerow [
               uitext "Height" 0.6
               UIhslider UI_jph -128 128 1 0.5 0.032 [uitext $UI_jph 0.6]
               uialign* -1 0
            ]
            uitablerow [
               uitext "X Lateral" 0.6
               UIhslider UI_jpx -127 127 1 0.5 0.032 [uitext $UI_jpx 0.6]
               uialign* -1 0
            ]
            uitablerow [
               uitext "Y Lateral" 0.6
               UIhslider UI_jpy -127 127 1 0.5 0.032 [uitext $UI_jpy 0.6]
               uialign* -1 0
            ]
         ]
         uifill 0 0.025
         UIbutton "" [uitext "Add" 0.6] 0.12 0.06 [hideui "ent_jumppad" ; newent jumppad $UI_jph $UI_jpx $UI_jpy]
      ]
   ]
] [] [] [] "Add Entity - Jumppad"

UImenu "ent_particles" [
   uispace 0.008 0.015 [
      uivlist 0 [
         uifill 0.5 0.032 [
            uitext (concatword "^f8/newent particles ") 0.7
            uialign* -1 0
            uioutline $c_line ; uiclamp- 1 1 1 1
         ]
         uifill 0 0.025
         UIbutton "" [uitext "ToDo" 0.8] 0.3 0.2 [hidetopui]
      ]
   ]
] [] [] [] "Add Entity - Particles"

UI_tid = 0
UImenu "ent_teleport" [
   uispace 0.008 0.015 [
      uivlist 0 [
         uifill 0.5 0.032 [
            uitext (concatword "^f8/newent teleport " $UI_tid) 0.7
            uialign* -1 0
            uioutline $c_line ; uiclamp- 1 1 1 1
         ]
         uifill 0 0.025
         uihlist 0.005 [
            uitext "ID#" 0.6
            UIhslider UI_tid 0 127 1 0.5 0.032 [uitext $UI_tid 0.6]
            uialign* -1 0
         ]
         uifill 0 0.025
         UIbutton "" [uitext "Add" 0.6] 0.12 0.06 [hideui "ent_teleport" ; newent teleport $UI_tid]
      ]
   ]
] [] [] [] "Add Entity - Teleport"
UImenu "ent_teledest" [
   uispace 0.008 0.015 [
      uivlist 0 [
         uifill 0.5 0.032 [
            uitext (concatword "^f8/newent teledest " $UI_tid) 0.7
            uialign* -1 0
            uioutline $c_line ; uiclamp- 1 1 1 1
         ]
         uifill 0 0.025
         uihlist 0.005 [
            uitext "ID#" 0.6
            UIhslider UI_tid 0 127 1 0.5 0.032 [uitext $UI_tid 0.6]
            uialign* -1 0
         ]
         uifill 0 0.025
         UIbutton "" [uitext "Add" 0.6] 0.12 0.06 [hideui "ent_teledest" ; newent teledest $UI_tid]
      ]
   ]
] [] [] [] "Add Entity - Teledest"

///////////////////////////////////////////////////////////////////////////////
//  F2 Texture Browser                                                       //
///////////////////////////////////////////////////////////////////////////////
UI_textabs = 0

// uitarget 0 0 [
//    uiimage "media/interface/directory.png" 0.145 0.145 [uispace 0 0.008 [uialign 0 1 ; uiclip 0.145 0 [uitext "directory" 0.55]]]
//    uihold [uioutline 0xC0C0C0; uiclamp- 1 1 1 1] [uihover [uioutline 0xFFFFFF; uiclamp- 1 1 1 1]]
//    uirelease [hideui "texture_browser"]
// ]

UImenu "texture_browser" [
   uihlist 0 [
      uifill 0 0 [
         uialign 0 -1
         uiclamp 1 1 1 1
         UIvtab 0.2 (*f 0.048 3) UI_textabs [
            0 "Listed"   [] // Listed Registered Cataloged
            1 "Utilized" [] // Used Utilized
            2 "Replace"  []
         ] 1
         uialign- 0 -1
         UIbutton "hold2" [
            UIcheckbox $allfaces 0.016
            uitext "Allfaces" 0.6
            UI_keyref 2 0.027 0.027 "6"
         ] 0.2 0.04 [allfaces (! $allfaces)]
         uialign- 0 1
      ]
      UIbar 0 1
      uifill 0.01
      case $UI_textabs 0 [//Listed/////////////////////////////////////////////////////////////////
         uiscroll 1.202875 0.7495 [
            uifill 1.202875 0.7495 [
               uigrid 8 0.006125 0.006125 [
                  loop slot (numslots) [
                     uislotview $slot 0.145 0.145 [
                        uihold [uioutline 0xC0C0C0; uiclamp- 1 1 1 1] [uihover [uioutline 0xFFFFFF; uiclamp- 1 1 1 1]]
                        uirelease [hideui "texture_browser"; settex (getslottex $slot)]
                     ]
                  ]
               ]
               uialign* -1 -1
            ]
         ]
         uifill 0.01
         UIvscroll 0.02 0.7495 3.0225
      ] 1 [//Utilized//////////////////////////////////////////////////////////////////////////////
         uiscroll 1.202875 0.7495 [
            uifill 1.202875 0.7495 [
               uigrid 8 0.006125 0.006125 [
                  looptexmru tex [
                     uivslotview $tex 0.145 0.145 [
                        uihold [uioutline 0xC0C0C0; uiclamp- 1 1 1 1] [uihover [uioutline 0xFFFFFF; uiclamp- 1 1 1 1]]
                        uirelease [hideui "texture_browser"; settex $tex]
                     ]
                  ]
               ]
               uialign* -1 -1
            ]
         ]
         uifill 0.01
         UIvscroll 0.02 0.7495 3.0225
      ] 2 [//Replace///////////////////////////////////////////////////////////////////////////////
         uifill 1.232875 0.7495 [
            UIbutton "" [uitext "ToDo" 0.8] 0.25 0.1 [hidetopui]
         ]
      ]
   ]
] [] [] [] "Texture Browser"

///////////////////////////////////////////////////////////////////////////////
//  F3 Mapmodel                                                              //
///////////////////////////////////////////////////////////////////////////////
newui "mapmodel" [
   uialign -1 -1
   uieschide 0
   uicolor $c_menu_a 0 0 [
      uispace $UIwindow_padding $UIwindow_padding [
         uiclamp 1 1 1 1
         uihlist 0.01 [
            if 0 [
               UIvscroll 0.02 0.81 (*f (min (+ 1 (div $nummapmodels 100)) 10) 5.4)
            ] [
               UIvscroll 0.02 0.81 (*f (min (+ 1 (div $nummapmodels 50)) 5) 2.7)
            ]
            uiscroll 0 0.81 [
               uivlist 0 [
                  uigrid 2 0 0 [// (+ $_res_wide 1)
                     loop i $nummapmodels [
                        uigroup [
                           uimodelpreview (mapmodelname $i 1) "mapmodel" 0.12 0.135 [
                              uihover [
                                 uihold [uioutline 0xFFFFFF] [
                                    uieschold [uioutline 0xFFFFFF] [
                                       uioutline 0x80FFFFFF
                                    ]
                                 ]
                                 uiclamp* 1 1 1 1
                                 UI_selmdl = $i
                                 uirelease [
                                    newent mapmodel $i
                                    _io_mapmodel = 0
                                 ]
                                 uiescrelease [
                                    if (enthavesel) [
                                       entset "mapmodel" $i
                                       _io_mapmodel = 0
                                    ]
                                 ]
                              ] [
                                 if (= $UI_selmdl $i) [
                                    uioutline 0x40FFFFFF
                                    uiclamp- 1 1 1 1
                                 ]
                              ]
                           ]
                           uispace 0.01 0.006 [
                              uialign -1 -1
                              uicolortext $i 0x80FFFFFF 0.6
                           ]
                        ]
                     ]
                  ]
               ]
            ]
         ]
      ]
      uioutline $c_line ; uiclamp- 1 1 1 1
   ]
   uiclamp* 1 1 1 1
] [
   UI_selmdl = -1
   hideui "texture"
   hideui "addentity"
]

///////////////////////////////////////////////////////////////////////////////
//  F4 Material Volume                                                       //
///////////////////////////////////////////////////////////////////////////////
UImenu "material" [
   uispace 0.008 0.015 [
      uivlist 0 [
         uifill 0.5 0.032 [
            uitext (concatword "^f8/" $UI_mattype) 0.7
            uialign* -1 0
            uioutline $c_line ; uiclamp- 1 1 1 1
         ]
         uifill 0 0.025
         uihlist 0.005 [
            uivlist 0.005 [
               UIbutton "" [uitext "Air (Clear)" 0.6] 0.15 0.04 [editmat air]      -1 [uihover [UI_mattype = "air"]]
               UIbutton "" [uitext "Clip" 0.6]        0.15 0.04 [editmat clip]     -1 [uihover [UI_mattype = "clip"]]
               UIbutton "" [uitext "No-Clip" 0.6]     0.15 0.04 [editmat noclip]   -1 [uihover [UI_mattype = "noclip"]]
               UIbutton "" [uitext "Gameclip" 0.6]    0.15 0.04 [editmat gameclip] -1 [uihover [UI_mattype = "gameclip"]]
               UIbutton "" [uitext "Death" 0.6]       0.15 0.04 [editmat death]    -1 [uihover [UI_mattype = "death"]]
               UIbutton "" [uitext "Alpha" 0.6]       0.15 0.04 [editmat alpha]    -1 [uihover [UI_mattype = "alpha"]]
            ]
            uivlist 0.005 [
               UIbutton "" [uitext "Glass 1" 0.6]     0.15 0.04 [editmat glass]    -1 [uihover [UI_mattype = "glass"]]
               UIbutton "" [uitext "Glass 2" 0.6]     0.15 0.04 [editmat glass2]   -1 [uihover [UI_mattype = "glass2"]]
               UIbutton "" [uitext "Glass 3" 0.6]     0.15 0.04 [editmat glass3]   -1 [uihover [UI_mattype = "glass3"]]
               UIbutton "" [uitext "Glass 4" 0.6]     0.15 0.04 [editmat glass4]   -1 [uihover [UI_mattype = "glass4"]]
            ]
            uivlist 0.005 [
               UIbutton "" [uitext "Lava 1" 0.6]      0.15 0.04 [editmat lava]     -1 [uihover [UI_mattype = "lava"]]
               UIbutton "" [uitext "Lava 2" 0.6]      0.15 0.04 [editmat lava2]    -1 [uihover [UI_mattype = "lava2"]]
               UIbutton "" [uitext "Lava 3" 0.6]      0.15 0.04 [editmat lava3]    -1 [uihover [UI_mattype = "lava3"]]
               UIbutton "" [uitext "Lava 4" 0.6]      0.15 0.04 [editmat lava4]    -1 [uihover [UI_mattype = "lava4"]]
            ]
            uivlist 0.005 [
               UIbutton "" [uitext "Water 1" 0.6]     0.15 0.04 [editmat water]    -1 [uihover [UI_mattype = "water"]]
               UIbutton "" [uitext "Water 2" 0.6]     0.15 0.04 [editmat water2]   -1 [uihover [UI_mattype = "water2"]]
               UIbutton "" [uitext "Water 3" 0.6]     0.15 0.04 [editmat water3]   -1 [uihover [UI_mattype = "water3"]]
               UIbutton "" [uitext "Water 4" 0.6]     0.15 0.04 [editmat water4]   -1 [uihover [UI_mattype = "water4"]]
            ]
            uialign* -1 -1
         ]
         uifill 0 0.01
         UIbutton "hold2" [
            UIcheckbox $showmat 0.016
            uitext "Show Material Volumes" 0.6
            UI_keyref 2 0.027 0.027 "M"
         ] 0.33 0.04 [showmat (! $showmat)]
      ]
   ]
] [UI_mattype = " "] [] [] "Material Volume"

///////////////////////////////////////////////////////////////////////////////
//  F5 Save Map                                                              //
///////////////////////////////////////////////////////////////////////////////
menu_savemap = [if (! $mapname) [toggleui "savemap"] [savemap]]
UI_mapname = "untitled"

UImenu "savemap" [
   uispace 0.008 0.015 [
      uivlist 0 [
         uihlist 0.01 [
            uitext "^f8/savemap " 0.7
            uifield UI_mapname 32 [] 0.7 style_generic_focus
         ]
         uifill 0 0.025
         UIbutton "" [uitext "Save" 0.6] 0.12 0.06 [savemap $UI_mapname]
      ]
   ]
] [] [] [] "Save Map"

///////////////////////////////////////////////////////////////////////////////
//  F6 Map Browser                                                           //
///////////////////////////////////////////////////////////////////////////////
UI_mapscale = 10
UI_maplist = 0
dmmaps = [
   complex alphacorp ot turbine reflection
]
ctfmaps = [
   alphacorp steelribs test_ctf reflection waterworks
]
tdmmaps = (listunion $dmmaps $ctfmaps)
allmaps = (listunion $dmmaps $ctfmaps)
testmaps = [
   test_anim test_model
]
editmaps = (listunion $dmmaps $ctfmaps $testmaps)

UImenu "map_browser" [
   uihlist 0.01 [
      uivlist 0 [
         uialign 0 -1
         UItitle [uiclip 0.3 0 [uitext $UI_selmap 0.7]] 0.3 0.03
         uimodcolor $c_boxmod 0.3 0.3 [
            uiclamp 1 1 1 1
            uiimage "media/interface/cube.png" 0.3 0.3 [uiimage (concatword "media/map/" $UI_selmap ".png") 0.3 0.3 [uiclamp 1 1 1 1]]
         ]
         uifill 0 0.015
         UItitle [uitext "List" 0.7] 0.3 0.03
         UIbutton "" [
            UIradio [= $UI_maplist 0] 0.016
            uitext "Tesseract" 0.6
         ] 0.3 0.03 [UI_maplist = 0 ; UI_selmap = ""] -1
         UIbutton "" [
            UIradio [= $UI_maplist 1] 0.016
            uitext "Custom" 0.6
         ] 0.3 0.03 [UI_maplist = 1 ; UI_selmap = ""] -1
         uifill 0.0 0.015
         UItitle [uitext "Gamemode" 0.7] 0.3 0.03
         uigrid 3 0 0 [
            nextmode = (getnextmode)
            looplist2 n i [
               "Edit"  0 "rDM"  1 "pDM"  2
               ""     -1 "rTDM" 3 "pTDM" 4
               ""     -1 "rCTF" 5 "pCTF" 6
            ] [
               if (< $i 0) [
                  uimodcolor $c_boxmod 0.1 0.03
               ] [
                  UIbutton "" [
                     UIradio [= $nextmode $i] 0.016
                     uitext $n 0.6
                  ] 0.1 0.03 [mode $i] -1
               ]
            ]
         ]
         uifill 0.0 0.015
         if (issomeoneelsemaster) [
            if (ismaster $getclientnum) [
               UIbutton "" [uitext (concatword (? (= $isconnected 1) (? (! $editing) "^f4")) "New Map") 0.7] 0.3 0.05 [hideui "map_browser" ; showui "newmap"]
            ] [
               UIbutton "" [uitext "^f4New Map" 0.65] 0.3 0.05 []
            ]
         ] [
            UIbutton "" [uitext (concatword (? (= $isconnected 1) (? (! $editing) "^f4")) "New Map") 0.7] 0.3 0.05 [hideui "map_browser" ; showui "newmap"]
         ]
      ]
      uiscroll 0.4 0.64 [
         uifill 0.37 0.64
         uivlist 0 [
            uialign 0 -1
            uiclamp 1 1
            if $UI_maplist [
               if (=s $custommaps "") [
                  custommaps = " "
                  loopfiles m "media/map" "ogz" [
                     if (< (indexof $editmaps $m) 0) [
                        custommaps = (concat $custommaps $m)
                     ]
                  ]
               ]
               looplist m $custommaps [
                  UIbutton (? (!=s $UI_selmap $m) "hold2") [
                     uitext $m 0.6
                  ] 0 0.04 [
                     hideui "loadmap"
                     map $m
                  ] -1 [uihover [UI_selmap = $m]]
               ]
            ] [
               looplist m $(? (m_ctf $nextmode) "ctfmaps" (? (m_edit $nextmode) "editmaps" (? (m_teammode $nextmode) "tdmmaps" "dmmaps"))) [
                  UIbutton (? (!=s $UI_selmap $m) "hold2") [
                     uitext $m 0.6
                  ] 0 0.04 [
                     hideui "loadmap"
                     map $m
                  ] -1 [uihover [UI_selmap = $m]]
               ]
            ]
            uiclamp* 1 1
         ]
      ]
      UIvscroll 0.02 0.64 1.6
   ]
] [
   UI_selmap = ""
   custommaps = ""
   hideui "newmap"
] [] [] "Map Browser"

UImenu "newmap" [
   uispace 0.008 0.015 [
      uivlist 0 [
         uifill 0.5 0.032 [
            uitext (concatword "^f8/newmap " (? (!= $UI_mapscale 10) $UI_mapscale)) 0.7
            uialign* -1 0
            uioutline $c_line ; uiclamp- 1 1 1 1
         ]
         uifill 0 0.025
         uihlist 0.01 [
            uitext "MapScale" 0.6
            UIhslider UI_mapscale 10 16 1 0.5 0.032 [uitext $UI_mapscale 0.6]
            uialign* -1 0
         ]
         uifill 0 0.025
         UIbutton "" [uitext (concatword (? (= $isconnected 1) (? (! $editing) "^f4")) "New") 0.6] 0.12 0.06 [hideui "newmap" ; newmap $UI_mapscale]
      ]
   ]
] [] [] [] "New Map"

///////////////////////////////////////////////////////////////////////////////
//  F7 Environment Settings                                                  //
///////////////////////////////////////////////////////////////////////////////
UI_envtabs = 0

UImenu "env_settings" [
   uihlist 0 [
      UIvtab 0.2 (*f 0.048 7) UI_envtabs [
         0 "Lighting" []
         1 "Sky"      []
         2 [@@(concatword (? (! $atmo) "^f4") "Dynamic-Sky")] []
         3 "Fog"      []
         4 "Water"    []
         5 "Lava"     []
         6 "Glass"    []
      ] 1
      uialign- 0 -1
      UIbar 0 1
      uifill 0.02
      uiscroll 0.67 0.6 [
         uifill 0.67 0.6 [
            uialign 0 -1
            uitable 0 0 [
               uialign -1 -1
               case $UI_envtabs 0 [//Lighting//////////////////////////////////////////////////////
                  uitablerow [
                     UIbutton "" [uitext "Lighting" 0.8] 0.25 0.1 [hidetopui]
                  ]
               ] 1 [//Sky//////////////////////////////////////////////////////////////////////////
                  uitablerow [
                     UIbutton "" [uitext "Sky" 0.8] 0.25 0.1 [hidetopui]
                  ]
               ] 2 [//Dynamic-Sky//////////////////////////////////////////////////////////////////
                  uitablerow [
                     UIbutton "" [uitext "Dynamic-Sky" 0.8] 0.25 0.1 [hidetopui]
                  ]
               ] 3 [//Fog//////////////////////////////////////////////////////////////////////////
                  uitablerow [
                     UIbutton "" [uitext "Fog" 0.8] 0.25 0.1 [hidetopui]
                  ]
               ] 4 [//Water////////////////////////////////////////////////////////////////////////
                  uitablerow [
                     UIbutton "" [uitext "Water" 0.8] 0.25 0.1 [hidetopui]
                  ]
               ] 5 [//Lava/////////////////////////////////////////////////////////////////////////
                  uitablerow [
                     UIbutton "" [uitext "Lava" 0.8] 0.25 0.1 [hidetopui]
                  ]
               ] 6 [//Glass////////////////////////////////////////////////////////////////////////
                  uitablerow [
                     UIbutton "" [uitext "Glass" 0.8] 0.25 0.1 [hidetopui]
                  ]
               ]
            ]
         ]
      ]
      UIvscroll 0.02 0.6 1.421 0.5
   ]
] [] [] [] "Environment Settings"

///////////////////////////////////////////////////////////////////////////////
//  F8 World Geometry Prefab                                                 //
///////////////////////////////////////////////////////////////////////////////
UImenu "geo_prefab" [
   uifill 0.5 0.5 [
      UIbutton "" [uitext "ToDo" 0.8] 0.3 0.2 [hidetopui]
   ]
] [] [] [] "World Geometry Prefab"

///////////////////////////////////////////////////////////////////////////////
//  F9 Miscellaneous Editing                                                 //
///////////////////////////////////////////////////////////////////////////////
UImenu "misc_editing" [
   uifill 0.5 0.5 [
      UIbutton "" [uitext "ToDo" 0.8] 0.3 0.2 [hidetopui]
   ]
] [] [] [] "Miscellaneous Editing"

///////////////////////////////////////////////////////////////////////////////
//  F10 Default Keybind Reference                                            //
///////////////////////////////////////////////////////////////////////////////
// UI_keyref 1:MODE(0=none,1=game,2=edit,3=move) 2:WIDTH(0=default) 3:HEIGHT(0=default) 4:NAME1 5:NAME2 6:TEXTSIZE(0=default)
// UI_keyref * 0.027 0.027 "*"    (Key Reference)
UI_keyref = [
   if $arg2 [] [arg2 = 0.04]
   if $arg3 [] [arg3 = 0.04]
   if $arg6 [] [arg6 = 0.5]
   uicolor (at [0x505050 0x496F37 0x2A707B 0x955524] $arg1) $arg2 $arg3 [
      if $arg5 [
         uivlist 0 [uitext $arg4 $arg6 ; uitext $arg5 $arg6]
      ] [
         uitext $arg4 $arg6
      ]
   ]
]

UImenu "editbind_reference" [
   uispace 0.005 0.005 [
      uivlist 0 [
         uihlist 0 [
            uigrid 3 0 0 [
               looplist a [
                  "^f9ESC"      "^f4 = " "^f9Main ^f4(Menu)"
                  "^f8F1"       "^f4 = " "^f8Add/Edit Entity ^f4(Menu)"
                  "^f8F2"       "^f4 = " "^f8Texture List ^f4(Menu)"
                  "^f8F3"       "^f4 = " "^f8Add Mapmodel ^f4(Menu)"
                  "^f8F4"       "^f4 = " "^f8Material Volume ^f4(Menu)"
                  " "           " "      " "
                  "^f8F5"       "^f4 = " "^f8Savemap ^f4(Menu)"
                  "^f9F6"       "^f4 = " "^f9Loadmap ^f4(Menu)"
                  "^f8F7"       "^f4 = " "^f8Environment Settings ^f4(Menu)"
                  "^f8F8"       "^f4 = " "^f8World Geometry Prefab ^f4(Menu)"
                  " "           " "      " "
                  "^f8F9"       "^f4 = " "^f8Miscellaneous Editing ^f4(Menu)"
                  "^f8F10"      "^f4 = " "^f8Keybind Reference ^f4(Menu)"
                  "^f9F11"      "^f4 = " "^f9Show Console"
                  "^f9F12"      "^f4 = " "^f9Take Screenshot"
                  " "           " "      " "
                  "^f9Pause"    "^f4 = " "^f9Pause Game"
                  " "           " "      " "
                  "^f8Delete"   "^f4 = " "^f8Editdelete"
                  "^f8Home"     "^f4 = " "^f8Goto selection"
                  "^f8End"      "^f4 = " "^f8Goto selected entities"
                  " "           " "      "^f4(Hold & Mousewheel)"
                  "^f8PageUp"   "^f4 = " "^f8Console scroll up"
                  "^f8PageDown" "^f4 = " "^f8Console scroll to end"
               ] [uitext $a 0.42]
            ]
            uispace 0.01 0 [UIbar 0 1 ; uiclamp 1 1 1 1]
            uigrid 3 0 0 [
               looplist a [
                  "^f8`" "^f4 = " "^f8Saycommand"
                  "^f81" "^f4 = " "^f8Edit Entity Attribute 0"
                  " "    " "      "^f4(Hold & Mousewheel)"
                  "^f82" "^f4 = " "^f8Edit Entity Attribute 1"
                  " "    " "      "^f4(Hold & Mousewheel)"
                  "^f83" "^f4 = " "^f8Edit Entity Attribute 2"
                  " "    " "      "^f4(Hold & Mousewheel)"
                  "^f84" "^f4 = " "^f8Edit Entity Attribute 3"
                  " "    " "      "^f4(Hold & Mousewheel)"
                  "^f85" "^f4 = " "^f8Edit Entity Attribute 4"
                  " "    " "      "^f4(Hold & Mousewheel)"
                  "^f86" "^f4 = " "^f8Toggle texture allfaces"
                  "^f87" "^f4 = " "^f8Toggle entity snapping"
                  "^f88" "^f4 = " "^f8Toggle entity editing"
                  "^f89" "^f4 = " "^f8Edit selected entity in console"
                  "^f90" "^f4 = " "^f9Show Master Menu"
                  "^f8-" "^f4 = " "^f8Toggle outline"
                  "^f8=" "^f4 = " "^f8Toggle wireframe"
                  " "    " "      " "
                  "^f8Q" "^f4 = " "^f8Push geometry corner pointed at"
                  " "    " "      "^f4(Hold & Mousewheel)"
                  "^f9E" "^f4 = " "^f9Edittoggle"
                  "^f8R" "^f4 = " "^f8Rotate geometry/blend-brush"
                  " "    " "      "^f4(Hold & Mousewheel)"
                  "^f9T" "^f4 = " "^f9Chat"
                  "^f8Y" "^f4 = " "^f8Scroll through textures"
                  " "    " "      "^f4(Hold & Mousewheel)"
                  "^f8U" "^f4 = " "^f8Undo"
                  "^f8I" "^f4 = " "^f8Redo"
                  "^f8O" "^f4 = " "^f8Texture offset horizontal ^f4(vslot)"
                  " "    " "      "^f4(Hold & Mousewheel)"
                  "^f8P" "^f4 = " "^f8Texture offset vertical ^f4(vslot)"
                  " "    " "      "^f4(Hold & Mousewheel)"
               ] [uitext $a 0.42]
            ]
            uispace 0.01 0 [UIbar 0 1 ; uiclamp 1 1 1 1]
            uigrid 3 0 0 [
               looplist a [
                  "^f8F"          "^f4 = " "^f8Push face/corner selected"
                  " "             " "      "^f4(Hold & Mousewheel)"
                  "^f8G"          "^f4 = " "^f8Change gridsize"
                  " "             " "      "^f4(Hold & Mousewheel)"
                  "^f8H"          "^f4 = " "^f8Toggle heightmap mode"
                  "^f8K"          "^f4 = " "^f8Calculate Lighting/Remip/Smoothing"
                  "^f8L"          "^f4 = " "^f8Toggle fullbright"
                  " "             " "      " "
                  "^f8Z"          "^f4 = " "^f8Repeat last saycommand"
                  "^f8X"          "^f4 = " "^f8Mirror Selection"
                  "^f8C"          "^f4 = " "^f8Copy Selection"
                  "^f8V"          "^f4 = " "^f8Paste Selection"
                  "^f8B"          "^f4 = " "^f8Change heightmap mode brush"
                  " "             " "      "^f4(Hold & Mousewheel)"
                  "^f8N"          "^f4 = " "^f8Find all entities of selected type"
                  "^f8M"          "^f4 = " "^f8Toggle show material volumes"
                  "^f8,"          "^f4 = " "^f8Rotate texture ^f4(vslot)"
                  " "             " "      "^f4(Hold & Mousewheel)"
                  "^f8."          "^f4 = " "^f8Scale texture ^f4(vslot)"
                  " "             " "      "^f4(Hold & Mousewheel)"
                  " "             " "      " "
                  "^f9TAB"        "^f4 = " "^f9Show scoreboard"
                  "^f8Left SHIFT" "^f4 = " "^f8Floatspeed 1000"
                  " "             " "      "^f4(Hold)"
                  "^f8Left CTRL"  "^f4 = " "^f8Select passthrough"
                  "^f8Left ALT"   "^f4 = " "^f8Edit entity x10"
                  " "             " "      "^f4(Hold with 1,2,3,4,5)"
                  "^f8SPACE"      "^f4 = " "^f8Cancel Selection"
                  "^f8Right ALT"  "^f4 = " "^f8Texture offset by 32px"
                  " "             " "      "^f4(Default 16px)"
                  " "             " "      "^f4(Hold with O or P)"
                  "^f9ENTER"      "^f4 = " "^f9Chat"
               ] [uitext $a 0.42]
            ]
            uispace 0.01 0 [UIbar 0 1 ; uiclamp 1 1 1 1]
            uigrid 3 0 0 [
               looplist a [
                  "^f8KP 0"          "^f4 = " "^f8Exit paint blendmap"
                  "^f8KP 2"          "^f4 = " "^f8Paint"
                  "^f8KP 5"          "^f4 = " "^f8Erase"
                  "^f8KP 8"          "^f4 = " "^f8Select blendbrush -"
                  "^f8KP 9"          "^f4 = " "^f8Select blendbrush +"
                  "^f8KP +"          "^f4 = " "^f8Toggle selection move/cut"
                  "^f8KP /"          "^f4 = " "^f8Floatspeed 10"
                  "^f8KP *"          "^f4 = " "^f8Floatspeed 50"
                  "^f8KP -"          "^f4 = " "^f8Floatspeed 100"
                  "^f8KP ENTER"      "^f4 = " "^f8Select entities within"
                  " "                " "      "^f8selection volume"
                  " "                " "      " "
                  "^f8Mouse Left"    "^f4 = " "^f8Select geometry/entities"
                  "^f8Mouse Middle"  "^f4 = " "^f8Select corners"
                  "^f8Mouse Right"   "^f4 = " "^f8Select extend/move/cut"
                  "^f8Mouse Scroll"  "^f4 = " "^f8Push Geometry"
                  "^f8Mouse Back"    "^f4 = " "^f8Toggle selection move/cut"
                  "^f8Mouse Forward" "^f4 = " "^f8Toggle selection move/cut"
               ] [uitext $a 0.42]
            ]
            uialign* -1 -1
         ]
         uifill 0 0.01
         uivlist 0.003 [
            uihlist 0.003 [
               UI_keyref 1 0     0 "ESC"
               uifill 0.03 0.04
               UI_keyref 2 0     0 "F1"
               UI_keyref 2 0     0 "F2"
               UI_keyref 2 0     0 "F3"
               UI_keyref 2 0     0 "F4"
               uifill 0.02 0.04
               UI_keyref 2 0     0 "F5"
               UI_keyref 1 0     0 "F6"
               UI_keyref 2 0     0 "F7"
               UI_keyref 2 0     0 "F8"
               uifill 0.02 0.04
               UI_keyref 2 0     0 "F9"
               UI_keyref 2 0     0 "F10"
               UI_keyref 1 0     0 "F11"
               UI_keyref 1 0     0 "F12"
               uifill 0.01 0.04
               UI_keyref 0 0     0 "Print"  "Screen" 0.32
               UI_keyref 0 0     0 "Scroll" "Lock"   0.32
               UI_keyref 1 0     0 "Pause"  ""       0.32
            ]
            uifill 0 0.01
            uihlist 0.003 [
               UI_keyref 1 0     0 "`"
               UI_keyref 2 0     0 "1"
               UI_keyref 2 0     0 "2"
               UI_keyref 2 0     0 "3"
               UI_keyref 2 0     0 "4"
               UI_keyref 2 0     0 "5"
               UI_keyref 2 0     0 "6"
               UI_keyref 2 0     0 "7"
               UI_keyref 2 0     0 "8"
               UI_keyref 2 0     0 "9"
               UI_keyref 1 0     0 "0"
               UI_keyref 2 0     0 "-"
               UI_keyref 2 0     0 "="
               UI_keyref 0 0.076 0 "BACK"
               uifill 0.01 0.04
               UI_keyref 0 0     0 "Insert" ""     0.32
               UI_keyref 2 0     0 "Home"   ""     0.32
               UI_keyref 1 0     0 "Page"   "Up"   0.32
               uifill 0.01 0.04
               UI_keyref 0 0     0 "Num"    "Lock" 0.32
               UI_keyref 2 0     0 "/"
               UI_keyref 2 0     0 "*"
               UI_keyref 2 0     0 "-"
            ]
            uihlist 0.003 [
               UI_keyref 1 0.060 0 "TAB"
               UI_keyref 2 0     0 "Q"
               UI_keyref 3 0     0 "W"
               UI_keyref 1 0     0 "E"
               UI_keyref 2 0     0 "R"
               UI_keyref 1 0     0 "T"
               UI_keyref 2 0     0 "Y"
               UI_keyref 2 0     0 "U"
               UI_keyref 2 0     0 "I"
               UI_keyref 2 0     0 "O"
               UI_keyref 2 0     0 "P"
               UI_keyref 0 0     0 "["
               UI_keyref 0 0     0 "]"
               UI_keyref 0 0.056 0 "\"
               uifill 0.01 0.04
               UI_keyref 2 0     0 "Delete" ""     0.32
               UI_keyref 2 0     0 "End"    ""     0.32
               UI_keyref 1 0     0 "Page"   "Down" 0.32
               uifill 0.01 0.04
               UI_keyref 0 0     0 "7"
               UI_keyref 2 0     0 "8"
               UI_keyref 2 0     0 "9"
               UI_keyref 2 0     0 "+"
            ]
            uihlist 0.003 [
               UI_keyref 0 0.072 0 "CAPS"
               UI_keyref 3 0     0 "A"
               UI_keyref 3 0     0 "S"
               UI_keyref 3 0     0 "D"
               UI_keyref 2 0     0 "F"
               UI_keyref 2 0     0 "G"
               UI_keyref 2 0     0 "H"
               UI_keyref 0 0     0 "J"
               UI_keyref 2 0     0 "K"
               UI_keyref 2 0     0 "L"
               UI_keyref 0 0     0 ";"
               UI_keyref 0 0     0 "'"
               UI_keyref 1 0.087 0 "ENTER"
               uifill 0.152 0.04
               UI_keyref 0 0     0 "4"
               UI_keyref 2 0     0 "5"
               UI_keyref 0 0     0 "6"
             //UI_keyref 2 0     0 "+"
            ]
            uihlist 0.003 [
               UI_keyref 2 0.100 0 "L SHIFT"
               UI_keyref 2 0     0 "Z"
               UI_keyref 2 0     0 "X"
               UI_keyref 2 0     0 "C"
               UI_keyref 2 0     0 "V"
               UI_keyref 2 0     0 "B"
               UI_keyref 2 0     0 "N"
               UI_keyref 2 0     0 "M"
               UI_keyref 2 0     0 ","
               UI_keyref 2 0     0 "."
               UI_keyref 0 0     0 "/"
               UI_keyref 0 0.102 0 "R SHIFT"
               uifill 0.053 0.04
               uicolor 0x955524 0.04 0.04 [UItriangle 0 0.01 0.01 0]
               uifill 0.053 0.04
               UI_keyref 0 0     0 "1"
               UI_keyref 2 0     0 "2"
               UI_keyref 0 0     0 "3"
               UI_keyref 2 0     0 "ENTER" "" 0.32
            ]
            uihlist 0.003 [
               UI_keyref 2 0.070 0 "LCTRL"
               uifill 0.0585 0.04
               UI_keyref 2 0.060 0 "LALT"
               UI_keyref 2 0.240 0 "SPACE"
               UI_keyref 2 0.060 0 "RALT"
               uifill 0.0585 0.04
               UI_keyref 0 0.070 0 "RCTRL"
               uifill 0.01 0.04
               uicolor 0x955524 0.04 0.04 [UItriangle 0 0.01 0.01 90]
               uicolor 0x955524 0.04 0.04 [UItriangle 0 0.01 0.01 180]
               uicolor 0x955524 0.04 0.04 [UItriangle 0 0.01 0.01 270]
               uifill 0.010 0.04
               UI_keyref 2 0.083 0 "0"
               UI_keyref 0 0     0 "."
             //UI_keyref 2 0     0 "ENTER" "" 0.32
            ]
            uialign* -1 -1
         ]
      ]
   ]
] [] [] [] "Default Editbind Reference"

UImenu "gamebind_reference" [
   uispace 0.005 0.005 [
      uivlist 0 [
         uihlist 0 [
            uigrid 3 0 0 [
               looplist a [
                  "^f9ESC"        "^f4 = " "^f9Main ^f4(Menu)"
                  " "             " "      " "
                  "^f9F6"         "^f4 = " "^f9Loadmap ^f4(Menu)"
                  "^f9F10"        "^f4 = " "^f9Keybind Reference ^f4(Menu)"
                  "^f9F11"        "^f4 = " "^f9Show Console"
                  "^f9F12"        "^f4 = " "^f9Take Screenshot"
                  " "             " "      " "
                  "^f9Pause"      "^f4 = " "^f9Pause Game"
                  " "             " "      " "
                  "^f9PageUp"     "^f4 = " "^f9Console scroll up"
                  "^f9PageDown"   "^f4 = " "^f9Console scroll to end"
                  " "             " "      " "
                  "^f9TAB"        "^f4 = " "^f9Show scoreboard"
                  "^f9Left SHIFT" "^f4 = " "^f9Crouch ^f4(Hold)"
                  "^f9Left CTRL"  "^f4 = " "^f9Crouch ^f4(Hold)"
                  "^f9SPACE"      "^f4 = " "^f9Jump"
                  "^f9ENTER"      "^f4 = " "^f9Chat"
               ] [uitext $a 0.42]
            ]
            uispace 0.01 0 [UIbar 0 1 ; uiclamp 1 1 1 1]
            uigrid 3 0 0 [
               looplist a [
                  "^f9`" "^f4 = " "^f9Saycommand"
                  "^f91" "^f4 = " "^f9Use Railgun"
                  "^f92" "^f4 = " "^f9Use Pulse Rifle"
                  "^f90" "^f4 = " "^f9Show Master Menu"
                  " "    " "    " "
                  "^f9E" "^f4 = " "^f9Edittoggle"
                  "^f9R" "^f4 = " "^f9Drop Flag"
                  "^f9T" "^f4 = " "^f9Chat"
                  "^f9Y" "^f4 = " "^f9Team Chat"
                  " "    " "    " "
                  "^f9F" "^f4 = " "^f9Melee attack"
                  " "    " "    " "
                  "^f9Z" "^f4 = " "^f9Toggle zoom"
               ] [uitext $a 0.42]
            ]
            uispace 0.01 0 [UIbar 0 1 ; uiclamp 1 1 1 1]
            uigrid 3 0 0 [
               looplist a [
                  "^f9Mouse Left"        "^f4 = " "^f9Attack"
                  "^f9Mouse Middle"      "^f4 = " "^f9Melee"
                  "^f9Mouse Right"       "^f4 = " "^f9Zoom"
                  " "                    " "    " "
                  "^f9Mouse Scroll-Up"   "^f4 = " "^f9Use Rocket"
                  "^f9Mouse Scroll-Down" "^f4 = " "^f9Use Rifle"
                  " "                    " "    " "
                  "^f9Mouse Back"        "^f4 = " "^f9Melee"
                  "^f9Mouse Forward"     "^f4 = " "^f9Melee"
               ] [uitext $a 0.42]
            ]
            uialign* -1 -1
         ]
         uifill 0 0.01
         uivlist 0.003 [
            uihlist 0.003 [
               UI_keyref 1 0     0 "ESC"
               uifill 0.03 0.04
               UI_keyref 1 0     0 "F1"
               UI_keyref 0 0     0 "F2"
               UI_keyref 0 0     0 "F3"
               UI_keyref 0 0     0 "F4"
               uifill 0.02 0.04
               UI_keyref 0 0     0 "F5"
               UI_keyref 1 0     0 "F6"
               UI_keyref 0 0     0 "F7"
               UI_keyref 0 0     0 "F8"
               uifill 0.02 0.04
               UI_keyref 0 0     0 "F9"
               UI_keyref 1 0     0 "F10"
               UI_keyref 1 0     0 "F11"
               UI_keyref 1 0     0 "F12"
               uifill 0.01 0.04
               UI_keyref 0 0     0 "Print"  "Screen" 0.32
               UI_keyref 0 0     0 "Scroll" "Lock"   0.32
               UI_keyref 1 0     0 "Pause"  ""       0.32
            ]
            uifill 0 0.01
            uihlist 0.003 [
               UI_keyref 1 0     0 "`"
               UI_keyref 1 0     0 "1"
               UI_keyref 1 0     0 "2"
               UI_keyref 0 0     0 "3"
               UI_keyref 0 0     0 "4"
               UI_keyref 0 0     0 "5"
               UI_keyref 0 0     0 "6"
               UI_keyref 0 0     0 "7"
               UI_keyref 0 0     0 "8"
               UI_keyref 0 0     0 "9"
               UI_keyref 1 0     0 "0"
               UI_keyref 0 0     0 "-"
               UI_keyref 0 0     0 "="
               UI_keyref 0 0.076 0 "BACK"
               uifill 0.01 0.04
               UI_keyref 0 0     0 "Insert" ""     0.32
               UI_keyref 0 0     0 "Home"   ""     0.32
               UI_keyref 1 0     0 "Page"   "Up"   0.32
               uifill 0.01 0.04
               UI_keyref 0 0     0 "Num"    "Lock" 0.32
               UI_keyref 0 0     0 "/"
               UI_keyref 0 0     0 "*"
               UI_keyref 0 0     0 "-"
            ]
            uihlist 0.003 [
               UI_keyref 1 0.060 0 "TAB"
               UI_keyref 0 0     0 "Q"
               UI_keyref 3 0     0 "W"
               UI_keyref 1 0     0 "E"
               UI_keyref 1 0     0 "R"
               UI_keyref 1 0     0 "T"
               UI_keyref 1 0     0 "Y"
               UI_keyref 0 0     0 "U"
               UI_keyref 0 0     0 "I"
               UI_keyref 0 0     0 "O"
               UI_keyref 0 0     0 "P"
               UI_keyref 0 0     0 "["
               UI_keyref 0 0     0 "]"
               UI_keyref 0 0.056 0 "\"
               uifill 0.01 0.04
               UI_keyref 0 0     0 "Delete" ""     0.32
               UI_keyref 0 0     0 "End"    ""     0.32
               UI_keyref 1 0     0 "Page"   "Down" 0.32
               uifill 0.01 0.04
               UI_keyref 0 0     0 "7"
               UI_keyref 0 0     0 "8"
               UI_keyref 0 0     0 "9"
               UI_keyref 0 0     0 "+"
            ]
            uihlist 0.003 [
               UI_keyref 0 0.072 0 "CAPS"
               UI_keyref 3 0     0 "A"
               UI_keyref 3 0     0 "S"
               UI_keyref 3 0     0 "D"
               UI_keyref 1 0     0 "F"
               UI_keyref 0 0     0 "G"
               UI_keyref 0 0     0 "H"
               UI_keyref 0 0     0 "J"
               UI_keyref 0 0     0 "K"
               UI_keyref 0 0     0 "L"
               UI_keyref 0 0     0 ";"
               UI_keyref 0 0     0 "'"
               UI_keyref 1 0.087 0 "ENTER"
               uifill 0.152 0.04
               UI_keyref 0 0     0 "4"
               UI_keyref 0 0     0 "5"
               UI_keyref 0 0     0 "6"
             //UI_keyref 0 0     0 "+"
            ]
            uihlist 0.003 [
               UI_keyref 1 0.100 0 "L SHIFT"
               UI_keyref 1 0     0 "Z"
               UI_keyref 0 0     0 "X"
               UI_keyref 0 0     0 "C"
               UI_keyref 0 0     0 "V"
               UI_keyref 0 0     0 "B"
               UI_keyref 0 0     0 "N"
               UI_keyref 0 0     0 "M"
               UI_keyref 0 0     0 ","
               UI_keyref 0 0     0 "."
               UI_keyref 0 0     0 "/"
               UI_keyref 0 0.102 0 "R SHIFT"
               uifill 0.053 0.04
               uicolor 0x955524 0.04 0.04 [UItriangle 0 0.01 0.01 0]
               uifill 0.053 0.04
               UI_keyref 0 0     0 "1"
               UI_keyref 0 0     0 "2"
               UI_keyref 0 0     0 "3"
               UI_keyref 0 0     0 "ENTER" "" 0.32
            ]
            uihlist 0.003 [
               UI_keyref 1 0.070 0 "LCTRL"
               uifill 0.0585 0.04
               UI_keyref 0 0.060 0 "LALT"
               UI_keyref 1 0.240 0 "SPACE"
               UI_keyref 0 0.060 0 "RALT"
               uifill 0.0585 0.04
               UI_keyref 0 0.070 0 "RCTRL"
               uifill 0.01 0.04
               uicolor 0x955524 0.04 0.04 [UItriangle 0 0.01 0.01 90]
               uicolor 0x955524 0.04 0.04 [UItriangle 0 0.01 0.01 180]
               uicolor 0x955524 0.04 0.04 [UItriangle 0 0.01 0.01 270]
               uifill 0.010 0.04
               UI_keyref 0 0.083 0 "0"
               UI_keyref 0 0     0 "."
             //UI_keyref 0 0     0 "ENTER" "" 0.32
            ]
            uialign* -1 -1
         ]
      ]
   ]
] [] [] [] "Default Gamebind Reference"

///////////////////////////////////////////////////////////////////////////////
//  F11 Fullscreen Console                                                   //
///////////////////////////////////////////////////////////////////////////////
newui "fullconsole" [
   uiallowinput 0
   uiclamp 1 1
   uialign 0 -1
   uicolor $c_menu_a 0 0 [
      uispace $UIwindow_padding $UIwindow_padding [
         uiclamp 1 1 1 1
         uiconsole 0 (divf $fullconsize 100) [uiclamp 1 1]
      ]
      uiclamp- 1 1 1 1
   ]
   uiclamp* 1 1 1 1
]
