83 lines
3.4 KiB
ArmAsm
83 lines
3.4 KiB
ArmAsm
/*
|
|
Copyright Oliver Kowalke 2009.
|
|
Distributed under the Boost Software License, Version 1.0.
|
|
(See accompanying file LICENSE_1_0.txt or copy at
|
|
http://www.boost.org/LICENSE_1_0.txt)
|
|
*/
|
|
|
|
/****************************************************************************************
|
|
* *
|
|
* ---------------------------------------------------------------------------------- *
|
|
* | 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | *
|
|
* ---------------------------------------------------------------------------------- *
|
|
* | 0x0 | 0x4 | 0x8 | 0xc | 0x10 | 0x14 | 0x18 | 0x1c | *
|
|
* ---------------------------------------------------------------------------------- *
|
|
* | fc_mxcsr|fc_x87_cw| R12 | R13 | R14 | *
|
|
* ---------------------------------------------------------------------------------- *
|
|
* ---------------------------------------------------------------------------------- *
|
|
* | 8 | 9 | 10 | 11 | 12 | 13 | 14 | 15 | *
|
|
* ---------------------------------------------------------------------------------- *
|
|
* | 0x20 | 0x24 | 0x28 | 0x2c | 0x30 | 0x34 | 0x38 | 0x3c | *
|
|
* ---------------------------------------------------------------------------------- *
|
|
* | R15 | RBX | RBP | RIP | *
|
|
* ---------------------------------------------------------------------------------- *
|
|
* *
|
|
****************************************************************************************/
|
|
|
|
.file "make_x86_64_sysv_elf_gas.S"
|
|
.text
|
|
.globl ostd_make_fcontext
|
|
.type ostd_make_fcontext,@function
|
|
.align 16
|
|
ostd_make_fcontext:
|
|
/* first arg of ostd_make_fcontext() == top of context-stack */
|
|
movq %rdi, %rax
|
|
|
|
/* shift address in RAX to lower 16 byte boundary */
|
|
andq $-16, %rax
|
|
|
|
/* reserve space for context-data on context-stack */
|
|
/* on context-function entry: (RSP -0x8) % 16 == 0 */
|
|
leaq -0x40(%rax), %rax
|
|
|
|
/* third arg of ostd_make_fcontext() == address of context-function */
|
|
/* stored in RBX */
|
|
movq %rdx, 0x28(%rax)
|
|
|
|
/* save MMX control- and status-word */
|
|
stmxcsr (%rax)
|
|
/* save x87 control-word */
|
|
fnstcw 0x4(%rax)
|
|
|
|
/* compute abs address of label trampoline */
|
|
leaq trampoline(%rip), %rcx
|
|
/* save address of trampoline as return-address for context-function */
|
|
/* will be entered after calling ostd_jump_fcontext() first time */
|
|
movq %rcx, 0x38(%rax)
|
|
|
|
/* compute abs address of label finish */
|
|
leaq finish(%rip), %rcx
|
|
/* save address of finish as return-address for context-function */
|
|
/* will be entered after context-function returns */
|
|
movq %rcx, 0x30(%rax)
|
|
|
|
ret /* return pointer to context-data */
|
|
|
|
trampoline:
|
|
/* store return address on stack */
|
|
/* fix stack alignment */
|
|
push %rbp
|
|
/* jump to context-function */
|
|
jmp *%rbx
|
|
|
|
finish:
|
|
/* exit code is zero */
|
|
xorq %rdi, %rdi
|
|
/* exit application */
|
|
call _exit@PLT
|
|
hlt
|
|
.size ostd_make_fcontext,.-ostd_make_fcontext
|
|
|
|
/* Mark that we don't need executable stack. */
|
|
.section .note.GNU-stack,"",%progbits
|